home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 15 / CU Amiga Magazine's Super CD-ROM 15 (1997)(EMAP Images)(GB)[!][issue 1997-10].iso / InitCD < prev    next >
AmigaDOS Script File  |  1997-08-15  |  5KB  |  159 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14.  
  15. Assign CUCD: :
  16.  
  17. ; Make some commands resident to speed up things on CD32s in particular
  18. Resident >NIL: CUCD:C/RequestChoice PURE
  19. Resident >NIL: CUCD:rexxc/rx PURE
  20. Resident >NIL: CUCD:C/Version PURE
  21.  
  22. If {arg} EQ "CHECK"         ; Exit if InitCD has been run, otherwise ask
  23.     If $CDInit EQ TRUE
  24.         Skip END
  25.     Else
  26.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  27.         If $init EQ 0
  28.             Skip END
  29.             EndIf
  30.         EndIf
  31.     EndIf
  32.  
  33. If $CDInit EQ TRUE
  34.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  35.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  36.         Skip END
  37.         EndIf
  38.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  39.     If $remass EQ 1
  40.         execute UnInitCD
  41.         EndIf
  42.     Skip END
  43.     EndIf
  44.  
  45. ; Set some system assigns
  46. Assign WWW:             CUCD:CUCD/WWW
  47. Assign GM:              CUCD:CDsupport/GMPlay ADD
  48. Assign CUCDNews:        CUCD:CUCD/Online/News
  49. Assign Twist:           CUCD:CUCD/Magazine/Issues
  50. Assign TwistIcon:       Twist:Icons
  51.  
  52. ; Add paths
  53. Path GM: ADD
  54.  
  55. ; Add MUI if no MUI installed.
  56. Assign MUI: EXISTS >NIL:
  57. IF WARN
  58.     Assign MUI:    CUCD:CDsupport/MUI
  59.     Assign Libs:   MUI:Libs ADD
  60.     Assign LOCALE: MUI:Locale ADD
  61.     Assign HELP: exists >NIL:
  62.     If NOT WARN
  63.         Dir >NIL: HELP:
  64.         EndIf
  65.     Assign HELP:   MUI:Docs ADD
  66. Else
  67.     :C/UpdateCopy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE DEEP
  68.     EndIf
  69.  
  70. ; Set assigns and paths for programs on this CD
  71. Execute CUCD:S/ThisCD
  72.  
  73. ;BEGIN ClassAct
  74. CUCD:C/CAPrefs >NIL:
  75. ;END ClassAct
  76.  
  77. ; start arexx if not running
  78. CUCD:rexxc/rx "address command" >NIL:
  79. If WARN
  80.     CUCD:System/RexxMast >NIL:
  81.     EndIf
  82.  
  83. IF $CDBoot EQ TRUE
  84.     Run <NIL: >NIL: CUCD:C/NewIcons
  85.     CUCD:C/DefIcons
  86. Else
  87.     ; All this is only needed when not booting from the CD
  88.     Run >NIL: RequestChoice "InitCD" "Setting up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on the Workbench." " OK "
  89.     Assign Fonts:   CUCD:Fonts ADD
  90.     Assign Libs:    CUCD:Libs ADD
  91.     Assign L:       CUCD:L ADD
  92.     Assign S:       CUCD:S ADD
  93.     Assign LIBS:    CUCD:Classes ADD
  94.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  95.  
  96.     ; Make environment variables defined on CD available to system
  97.     Failat 21
  98.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  99.     ; For HappyENV users
  100.     If FAIL     
  101.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  102.         EndIf
  103.  
  104.     ;Start NewIcons if not already running
  105.     If $NoNewIcons NOT EQ TRUE
  106.         CUCD:C/isnirunning
  107.         If NOT WARN
  108.             Run <NIL: >NIL: CUCD:C/NewIcons
  109.             CUCD:C/DefIcons
  110.             EndIf
  111.         EndIf
  112.  
  113.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  114.     Version >NIL: C:LoadWB 43
  115.     If WARN
  116.        C:LoadWB NEWPATH
  117.     Else
  118.         Version >NIL: C:LoadWB 60
  119.         If NOT WARN
  120.             C:LoadWB NEWPATH
  121.             EndIf
  122.         EndIf
  123.  
  124.     ; Check that libraries on boot drive are up to date
  125.     ;Execute CUCD:S/UpdateLibrary rexxdossupport.library 3 5
  126.     ;Execute CUCD:S/UpdateLibrary rexxreqtools.library  37 95
  127.     ;Execute CUCD:S/UpdateLibrary newicon.library 39 1
  128.     ;Execute CUCD:S/UpdateLibrary cando.library 3 8
  129.  
  130.     ; Give option for setting CD preferences
  131.     Version >NIL: version 37
  132.     If NOT WARN
  133.         If NOT EXISTS ENV:IDer.prefs
  134.             set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  135.             If $edit EQ 1
  136.                 cd CUCD:S
  137.                 :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  138.             else
  139.                 RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  140.                 EndIf
  141.             EndIf
  142.     Else
  143.         If NOT EXISTS ENV:IDer.prefs
  144.             Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  145.             EndIf
  146.         EndIf
  147.  
  148.     EndIf
  149.  
  150. SetEnv CDInit TRUE
  151.  
  152. LAB END
  153.  
  154. ; Remove commands made resident earlier
  155. Resident >NIL: RequestChoice REMOVE
  156. Resident >NIL: rx REMOVE
  157. Resident >NIL: Version REMOVE
  158.  
  159.